Führt einige einfache Aktionen im Browser aus.
#include <IE.au3>
_IEAction(ByRef $o_object, $s_action)
| $o_object | Objektvariable einer InternetExplorer.Application |
| $s_action | gewählte Aktion (siehe Bemerkungen) |
| Erfolg: | Rückgabe 1 |
| Fehler: | Rückgabe 0 und setzt @ERROR |
| @Error: | 0 ($_IEStatus_Success) = Kein Fehler |
| 3 ($_IEStatus_InvalidDataType) = Ungültiger Datentyp | |
| 4 ($_IEStatus_InvalidObjectType) = Ungültiger Objekttyp | |
| 5 ($_IEStatus_InvalidValue) = Ungültiger Wert | |
| @Extended: | Beinhaltet die Nummer des fehlerhaften Parameters |
| Aktion | Beschreibung |
| "back" | Geht in der Historyliste einen Eintrag rückwärts. |
| "blur" | Veranlasst das Element den Fokus zu verlieren, der Fokus wird jedoch nicht auf das nächste Element in der Tab-Reihenfolge gesetzt. |
| "click" | Simuliert einen Klick auf das angegebene Element. |
| "copy" | Kopiert die momentane Auswahl in die Zwischenablage. |
| "cut" | Kopiert die momentane Auswahl in die Zwischenablage und löscht sie danach. |
| "delete" | Löscht die momentane Auswahl. |
| "disable" | Deaktiviert das angegebene Element. |
| "enable" | Aktiviert das angegebene Element. |
| "focus" | Weist dem Element den Fokus zu. |
| "forward" | Geht in der Historyliste einen Eintrag vorwärts. |
| "home" | Geht zur momentanen Home- oder Startseite. |
| "invisible" | Setzt den Status des Objekts auf versteckt. |
| "paste" | Überschreibt die momentane Auswahl mit dem Inhalt der Zwischenablage. |
| "print" | Öffnet den Drucken Dialog, damit der Benutzer die momentane Seite drucken kann. |
| "printdefault" | Direkt mit dem Standard-Drucker drucken (kein Dialog). |
| "quit" | Schließt das Objekt. |
| "refresh" | Aktualisiert das momentane Dokument. |
| "saveas" | Öffnet die Dialogbox zum speichern der derzeitigen Webseite in eine Datei. |
| "search" | Geht zur momentanen "suchen"-Seite. |
| "selectall" | Wählt das ganze Dokument aus. |
| "stop" | Beendet alle nicht erledigte Aufrufe, Downloads und dynamische Seitenelemente, wie z.B. Hintergrundgeräusche und Animationen. |
| "unselect" | Hebt die momentane Auswahl auf. |
| "visible" | Setzt den Status des Objekts auf sichtbar. |
; *******************************************************
; Beispiel 1 - Öffnet das "form" - Beispiel im Standardbrowser.
; Nun wird ein Klick auf den Submit-Button simuliert, welcher
; anhand seiner Beschriftung erkannt wurde. Diese Technik
; ist sinnvoll, weil sehr viele Input-Controls über JavaScript gesteuert werden,
; bei welchen eine standardmäßige "onClick" Ereignisübergabe mit_IEFormSubmit()
; nicht immer dass gewünschte Ergebnis hervorruft.
; *******************************************************
#include <IE.au3>
Local $oIE = _IE_Example("form")
Local $oSubmit = _IEGetObjByName($oIE, "submitExample")
_IEAction($oSubmit, "click")
_IELoadWait($oIE)
; *******************************************************
; Beispiel 2 - Ähnlich wie Beispiel 1, nur dass hier dem gewünschten Element der Fokus übergeben
; wird und dann über ControlSend() Enter gesendet.
; Verwende diese Technik, wenn Skripte im Browser verhindern,
; dass AutoIt das Ende der Aktion mitbekommt und das Skript fortgesetzt wird.
; *******************************************************
#include <IE.au3>
$oIE = _IE_Example("form")
$oSubmit = _IEGetObjByName($oIE, "submitExample")
Local $hwnd = _IEPropertyGet($oIE, "hwnd")
_IEAction($oSubmit, "focus")
ControlSend($hwnd, "", "[CLASS:Internet Explorer_Server; INSTANCE:1]", "{Enter}")
; Wartet bis das Explorerfenster im Vordergrund ist, und klickt dann auf OK.
WinWait("Windows Internet Explorer", "ExampleFormSubmitted")
ControlClick("Windows Internet Explorer", "ExampleFormSubmitted", "[CLASS:Button; TEXT:OK; Instance:1;]")
_IELoadWait($oIE)