Funktionsreferenz

_SoundLength

Gibt die Länge einer Sounddatei zurück.

#include <Sound.au3>
_SoundLength($aSnd_id [, $iMode])

Parameter

$aSnd_id Sound ID Array welches durch _SoundOpen() zurückgegeben wurde oder ein Dateiname
$iMode [optional] Dieses Flag legt fest, in welchem Format die Länge der Sounddatei zurückgegeben werden soll
1 = hh:mm:ss wobei h = Stunden, m = Minuten und s = Sekunden sind
2 = Millisekunden

Rückgabewert

Erfolg: Soundlänge
Fehler: 0 und setzt @error
@Error: 1 = $iMode ist ungültig
3 = Ungültige Sound ID. Es ist das zurückgegebene Array von _SoundOpen() oder ein gültiger Dateiname zu verwenden.

Bemerkungen

Diese Funktion gibt den bestmöglichen Wert für die Länge der Datei zurück. Dabei wird die Enkodiermethode oder der Parametertyp nicht berücksichtigt.

Verwandte Funktionen

_SoundPos, _SoundOpen

Beispiel


#include <Sound.au3>

Local $sound = _SoundOpen(@WindowsDir & "\media\Windows XP Startup.wav")
If @error = 2 Then
    MsgBox(0, "Fehler", "Die Datei existiert nicht.")
    Exit
ElseIf @extended <> 0 Then
    Local $iExtended = @extended ; Zuweisung, weil @extended nach DllCall-Aufruf geändert wird
    Local $stText = DllStructCreate("char[128]")
    DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "ptr", DllStructGetPtr($stText), "int", 128)
    MsgBox(0, "Fehler", "Öffnen fehlgeschlagen." & @CRLF & "Fehlernummer: " & $iExtended & @CRLF & "Fehlerbeschreibung: " & DllStructGetData($stText, 1) & @CRLF & "Beachte: Möglicherweise kann der Sound dennoch korrekt abgespielt werden.")
Else
    MsgBox(0, "Erfolgsmeldung", "Die Datei wurde erfolgreich geöffnet.")
EndIf

MsgBox(0, "Sound-Länge", "Der Sound hat eine Spieldauer von: " & @CRLF & _
        _SoundLength($sound, 1) & @CRLF & "Millisekunden - " & _SoundLength($sound, 2))